Jazz Jackrabbit 2 Online

const array<string> paletteNames = {
	"Tube.j2t",
	"TubeNite.j2t",
	"InfernoN.j2t",
	"Labrat1.j2t",
	"Beach.j2t",
	"Diam1.j2t"
};
const uint8 CRATEDELAYTIME = 2*70;
uint8 elapsed0, elapsed1;

jjPLAYER@ play;

void onLevelLoad() {
	for (uint8 i = 1; i < jjLocalPlayerCount; i++) { //disallow cooperative players
		jjLocalPlayers[i].lives = 0;
		jjLocalPlayers[i].kill();
	}
	@play = jjLocalPlayers[0];
	jjChat("/fireball on");
}
void onFunction10(uint8 duration) { //JJ2 nulls certain jjPLAYER properties after onLevelLoad is called
	p.timerStart(duration*70,false);
	p.limitXScroll(1, 200);
}
void onLevelReload() {
	play.timerStart(6*70, false);
	play.limitXScroll(1, 200);
}
void onFunction0(uint8 id) {
	jjPalette.load(paletteNames[id]);
	jjPalette.apply();
}
void onFunction1() {
	p.kill();
}
void onPlayerTimerEnd() {
	p.warpToID(192,false);
	p.showText(0,0);
}
void onMain() {
	if (jjTriggers[0]) {
		switch(elapsed0++) {
			case 0:
				for (uint i = 0; i < 3; i++) jjTileSet(4, 44+i, 38, 0);
				break;
			case CRATEDELAYTIME:
				elapsed0 = 0;
				jjTriggers[0] = false;
				for (uint i = 0; i < 3; i++) jjTileSet(4, 44+i, 38, 109);
				jjAddObject(OBJECT::TRIGGERCRATE, 40*32, 37*32, 0, CREATOR::LEVEL);
				break;
		}
	}
	if (jjTriggers[1]) {
		switch(elapsed1++) {
			case 0:
				for (uint i = 0; i < 3; i++) jjTileSet(4, 44+i, 39, 0);
				break;
			case CRATEDELAYTIME:
				elapsed1 = 0;
				jjTriggers[1] = false;
				for (uint i = 0; i < 3; i++) jjTileSet(4, 44+i, 39, 119);
				jjAddObject(OBJECT::TRIGGERCRATE, 50*32, 37*32, 0, CREATOR::LEVEL);
				break;
		}
	}
}
void onFunction2(int8 y) {
	p.offsetPosition(0, y * 32);
}
void onFunction3()
{
	if (p.antiGrav) {
		p.activateBoss();
		p.showText(1,1);
		jjMusicLoad("onewingedangel.j2b") || jjMusicLoad("order.j2b");
		if (p.ammo[WEAPON::ICE] == 0) p.ammo[WEAPON::ICE] = 3;
		p.currWeapon = WEAPON::ICE;
		p.antiGrav = false;
	}
}