Jazz Jackrabbit 2 Online

const bool MLLESetupSuccessful = MLLE::Setup(); ///@MLLE-Generated
#include "MLLE-Include-1.6.asc" ///@MLLE-Generated
#pragma require "eztubo-MLLE-Data-4.j2l" ///@MLLE-Generated
#pragma require "eztubo-MLLE-Data-3.j2l" ///@MLLE-Generated
#pragma require "eztubo-MLLE-Data-2.j2l" ///@MLLE-Generated
#pragma require "eztubo-MLLE-Data-1.j2l" ///@MLLE-Generated
#pragma require "eztubo.j2l" ///@MLLE-Generated
#include "ammocharger.asc"

void onLevelBegin() {
	MLLE::SpawnOffgrids();
	jjTexturedBGFadePositionY = 1.25;
	jjLayers[7].reflection.blur = true;
	}
	
void onLevelReload() {
	MLLE::SpawnOffgridsLocal();
}

void onLevelLoad() {	
	for (int i = 1; i < 255; i++) {
		if (jjObjectPresets[i].playerHandling == HANDLING::PICKUP && i != 73) {
			jjObjectPresets[i].behavior = CannotBeShotDown;
		}
	}

	generateCustomSpringSprites(jjAnimSets[ANIM::CUSTOM[0]], array<uint> = {40});
	turnIntoCustomSpring(jjObjectPresets[OBJECT::FROZENSPRING], 0, 20.5f, false);


	jjObjectPresets[OBJECT::FULLENERGY].behavior = CantBeBuried;
	jjObjectPresets[OBJECT::BOUNCERBULLET].behavior = bouncer;
	
	superCharge(OBJECT::BOUNCERAMMO15, 30);
	superCharge(OBJECT::TOASTERAMMO15, 30);
}

void onPlayer(jjPLAYER@ play) {
	handleFastCustomSpringSpeeds(play);
	array<jjLAYER@> layers = jjLayerOrderGet();

    layers[15].hasTiles =  
	layers[16].hasTiles =
    layers[17].hasTiles =
    layers[26].hasTiles =
    layers[27].hasTiles =
    layers[29].hasTiles =
    layers[30].hasTiles =
    layers[31].hasTiles = jjColorDepth == 16? true:false;

	if (jjLayers[1].hasTiles && jjColorDepth == 16) {
		layers[15].hasTiles = 
		layers[16].hasTiles = 
		layers[17].hasTiles = true;
		for (uint i = 19; i <= layers.length() - 2; i++) {
			layers[i].hasTiles = true;
	}
	} else { 
		layers[15].hasTiles = 
		layers[16].hasTiles = 
		layers[17].hasTiles = false;
		for (uint i = 19; i <= layers.length() - 2; i++) {
			layers[i].hasTiles = false;
		}
	}
}

jjANIMSET@ customSpringSprite;
array<int> fastCustomSpringSpeeds(jjLocalPlayerCount);
bool generateCustomSpringSprites(jjANIMSET@ anim, const array<uint> &in colors) {
	int length = colors.length();
	bool success = (@customSpringSprite = anim).allocate(array<uint>(length * 3, 5)) !is null;
	if (success) {
		uint srcSet = jjAnimSets[ANIM::SPRING];
		for (int i = 0; i < length; i++) {
			uint color = colors[i];
			uint destAnimOffset = anim + i * 3;
			for (int j = 0; j < 3; j++) {
				uint srcAnim = jjAnimations[srcSet + j];
				uint destAnim = jjAnimations[destAnimOffset + j];
				for (int k = 0; k < 5; k++) {
					jjPIXELMAP image(jjAnimFrames[destAnim + k] = jjAnimFrames[srcAnim + k]);
					int width = image.width;
					int height = image.height;
					for (int l = 0; l < height; l++) {
						for (int m = 0; m < width; m++) {
							int pixel = image[m, l];
							if (pixel >= 32 && pixel < 40)
								image[m, l] = color + (pixel & 7);
						}
					}
					if (!image.save(jjAnimFrames[destAnim + k]))
						return false;
				}
			}
		}
	}
	return success;
}

void initializeCustomSpring(jjOBJ@ obj) {
	int anim = obj.curAnim;
	obj.behave(obj.behavior = BEHAVIOR::SPRING, false);
	if (obj.curAnim != anim) {
		obj.curAnim = anim + 2;
		obj.determineCurFrame();
	}
	obj.draw();
}

void turnIntoCustomSpring(jjOBJ@ obj, uint color, float power, bool horizontal) {
	if (horizontal) {
		obj.xSpeed = power;
		obj.ySpeed = 0.f;
	} else {
		obj.xSpeed = 0.f;
		obj.ySpeed = -power;
		if (obj.state == STATE::START && obj.creatorType == CREATOR::LEVEL) {
			int x = int(obj.xPos) >> 5;
			int y = int(obj.yPos) >> 5;
			if (jjParameterGet(x, y, 0, 1) != 0) {
				jjParameterSet(x, y, 0, 1, 0);
				obj.yPos -= 4.f;
				obj.ySpeed = power;
			}
		}
	}
	obj.behavior = initializeCustomSpring;
	obj.curAnim = customSpringSprite + color * 3 + (horizontal ? 1 : 0);
	obj.energy = obj.frameID = obj.freeze = obj.justHit = obj.light = obj.points = 0;
	obj.causesRicochet = obj.isTarget = obj.scriptedCollisions = obj.triggersTNT = false;
	obj.isBlastable = false;
	obj.deactivates = true;
	obj.isFreezable = true;
	obj.bulletHandling = HANDLING::IGNOREBULLET;
	obj.playerHandling = HANDLING::SPECIAL;
	obj.lightType = LIGHT::NORMAL;
	obj.determineCurFrame();
}

void handleFastCustomSpringSpeeds(jjPLAYER@ play) {
	if (play.ySpeed < -32.f) {
		fastCustomSpringSpeeds[play.localPlayerID] = int(ceil((play.ySpeed + 32.f) / -0.125f));
	} else if (fastCustomSpringSpeeds[play.localPlayerID] != 0) {
		if (play.ySpeed < -31.f) {
			fastCustomSpringSpeeds[play.localPlayerID]--;
			play.ySpeed = -32.f;
		} else {
			fastCustomSpringSpeeds[play.localPlayerID] = 0;
		}
	}
}

void CannotBeShotDown(jjOBJ@ obj) {
	obj.behave(BEHAVIOR::PICKUP);
	if (obj.state == STATE::FLOATFALL) obj.state = STATE::FLOAT;
}

void CantBeBuried(jjOBJ@ obj) {
	obj.behave(BEHAVIOR::PICKUP);
	if (jjMaskedPixel(int(obj.xPos), int(obj.yPos) + 8) && obj.xPos > 50*32 && obj.xPos < 57*32) {
		obj.state = STATE::FLOAT;
	}
}

void bouncer(jjOBJ@ obj) {
    float xSpeed = obj.xSpeed;
    float ySpeed = obj.ySpeed;
    obj.behave(BEHAVIOR::BOUNCERBULLET);
    if (xSpeed * obj.xSpeed < 0.f && ySpeed * obj.ySpeed < 0.f) {
        if (!jjMaskedPixel(int(obj.xPos + obj.xSpeed), int(obj.yPos + ySpeed))) {
            obj.var[0] = obj.var[0] - 1;
            obj.ySpeed = ySpeed;
            if (ySpeed > 0.f)
                obj.yPos += ySpeed;
        }
    }
}