Jazz Jackrabbit 2 Online

const bool MLLESetupSuccessful = MLLE::Setup(array<MLLEWeaponApply@> = {null, DuoBouncers::Weapon(), null, se::FireworkMLLEWrapper(), null, null, SpikeBomb::Weapon(), ArcaneWeapons::NailGun::Weapon(), null}); ///@MLLE-Generated
#include "MLLE-Include-1.7w.asc" ///@MLLE-Generated
#pragma require "xlmjolly-MLLE-Data-2.j2l" ///@MLLE-Generated
#pragma require "xlmjolly-MLLE-Data-1.j2l" ///@MLLE-Generated
#pragma require "xlmjolly.j2l" ///@MLLE-Generated
#include "ArcaneWeapon5.asc" ///@MLLE-Generated
#pragma require "ArcaneWeapon5.asc" ///@MLLE-Generated
#include "SpikeBomb.asc" ///@MLLE-Generated
#pragma require "SpikeBomb.asc" ///@MLLE-Generated
#include "SEfirework-mlle.asc" ///@MLLE-Generated
#pragma require "SEfirework-mlle.asc" ///@MLLE-Generated
#include "DuoBouncers.asc" ///@MLLE-Generated
#pragma require "DuoBouncers.asc" ///@MLLE-Generated
///@SaveAndRunArgs -server -battle ///@MLLE-Generated

void onLevelReload() {
	MLLE::SpawnOffgridsLocal();
	MLLE::ReapplyPalette();
}

bool onDrawAmmo(jjPLAYER@ player, jjCANVAS@ canvas) {
	return MLLE::WeaponHook.drawAmmo(player, canvas);
}

void onLevelLoad() {
	generateCustomSpringSprites(jjAnimSets[ANIM::CUSTOM[9]], array<uint> = {40, 48, 16, 88});
    turnIntoCustomSpring(jjObjectPresets[OBJECT::FROZENSPRING], 0, 19.75f, false);
    turnIntoCustomSpring(jjObjectPresets[OBJECT::HORREDSPRING], 1, 17.75f, false);
    turnIntoCustomSpring(jjObjectPresets[OBJECT::HORGREENSPRING], 2, 27.45f, false);
    turnIntoCustomSpring(jjObjectPresets[OBJECT::HORBLUESPRING], 3, 33.0f, false);

	jjObjectPresets[OBJECT::HORREDSPRING].causesRicochet = jjObjectPresets[OBJECT::HORBLUESPRING].causesRicochet = jjObjectPresets[OBJECT::HORGREENSPRING].causesRicochet = false;

	jjWeapons[WEAPON::GUN8].spread = SPREAD::NORMAL;
	jjObjectPresets[OBJECT::FIREBALLBULLETPU].var[6] = 8 + 16;

	jjPIXELMAP rockImage(0,0, 96,96, 5);
	jjANIMFRAME@ rockFrame = jjAnimFrames[jjObjectPresets[OBJECT::ROTATINGROCK].curFrame];
	rockImage.save(rockFrame);
	rockFrame.hotSpotY -= 8;
	
	uint giftAnimID = jjAnimSets[ANIM::CUSTOM[0]].allocate(array<uint> = {3,1,1,1,1, 3,1,1,1,1, 3,1,1,1,1});
	for (uint color = 0; color < 3; ++color, ++giftAnimID) {
		const uint y = (3 + color) * 32;
		for (uint state = 0; state < 3; ++state) {
			jjANIMFRAME@ boxFrame = jjAnimFrames[jjAnimations[giftAnimID] + state];
			jjPIXELMAP(state * 64 + 13, y, 48,32, 5).save(boxFrame);
			boxFrame.hotSpotX = -24;
			boxFrame.hotSpotY = 0;
		}
		for (uint shard = 0; shard < 4; ++shard) {
			jjANIMFRAME@ shardFrame = jjAnimFrames[jjAnimations[++giftAnimID]];
			jjPIXELMAP((6 + shard) * 32, y, 32,32, 5).save(shardFrame);
			shardFrame.hotSpotX = shardFrame.hotSpotY = -16;
		}
	}
	
	jjObjectPresets[OBJECT::GUNCRATE].behavior = 
	jjObjectPresets[OBJECT::CARROTCRATE].behavior = 
	jjObjectPresets[OBJECT::ONEUPCRATE].behavior = 
	jjObjectPresets[OBJECT::BOMBCRATE].behavior = 
	jjObjectPresets[OBJECT::SPRINGCRATE].behavior = 
	jjObjectPresets[OBJECT::GEMCRATE].behavior = 
	jjObjectPresets[OBJECT::BOUNCERAMMO15].behavior = 
	jjObjectPresets[OBJECT::ICEAMMO15].behavior = 
	jjObjectPresets[OBJECT::SEEKERAMMO15].behavior = 
	jjObjectPresets[OBJECT::RFAMMO15].behavior = 
	jjObjectPresets[OBJECT::TOASTERAMMO15].behavior = 
		Gift;
}			

void onMain() {	
	jjWeapons[WEAPON::GUN8].comesFromGunCrates = true;
        jjWeapons[WEAPON::GUN9].comesFromGunCrates = true;
}

jjANIMSET@ customSpringSprite;
array<int> fastCustomSpringSpeeds(jjLocalPlayerCount);
bool generateCustomSpringSprites(jjANIMSET@ anim, const array<uint> &in colors) {
    int length = colors.length();
    bool success = (@customSpringSprite = anim).allocate(array<uint>(length * 3, 5)) !is null;
    if (success) {
        uint srcSet = jjAnimSets[ANIM::SPRING];
        for (int i = 0; i < length; i++) {
            uint color = colors[i];
            uint destAnimOffset = anim + i * 3;
            for (int j = 0; j < 3; j++) {
                uint srcAnim = jjAnimations[srcSet + j];
                uint destAnim = jjAnimations[destAnimOffset + j];
                for (int k = 0; k < 5; k++) {
                    jjPIXELMAP image(jjAnimFrames[destAnim + k] = jjAnimFrames[srcAnim + k]);
                    int width = image.width;
                    int height = image.height;
                    for (int l = 0; l < height; l++) {
                        for (int m = 0; m < width; m++) {
                            int pixel = image[m, l];
                            if (pixel >= 32 && pixel < 40)
                                image[m, l] = color + (pixel & 7);
                        }
                    }
                    if (!image.save(jjAnimFrames[destAnim + k]))
                        return false;
                }
            }
        }
    }
    return success;
}
void initializeCustomSpring(jjOBJ@ obj) {
    int anim = obj.curAnim;
    obj.behave(obj.behavior = BEHAVIOR::SPRING, false);
    if (obj.curAnim != anim) {
        obj.curAnim = anim + 2;
        obj.determineCurFrame();
    }
    obj.draw();
}
 
void turnIntoCustomSpring(jjOBJ@ obj, uint color, float power, bool horizontal) {
    if (horizontal) {
        obj.xSpeed = power;
        obj.ySpeed = 0.f;
    } else {
        obj.xSpeed = 0.f;
        obj.ySpeed = -power;
        if (obj.state == STATE::START && obj.creatorType == CREATOR::LEVEL) {
            int x = int(obj.xPos) >> 5;
            int y = int(obj.yPos) >> 5;
            if (jjParameterGet(x, y, 0, 1) != 0) {
                jjParameterSet(x, y, 0, 1, 0);
                obj.yPos -= 4.f;
                obj.ySpeed = power;
            }
        }
    }
    obj.behavior = initializeCustomSpring;
    obj.curAnim = customSpringSprite + color * 3 + (horizontal ? 1 : 0);
    obj.energy = obj.frameID = obj.freeze = obj.justHit = obj.light = obj.points = 0;
    obj.isBlastable = obj.isTarget = obj.scriptedCollisions = obj.triggersTNT = false;
    obj.deactivates = obj.isFreezable = true;
    obj.bulletHandling = HANDLING::IGNOREBULLET;
    obj.playerHandling = HANDLING::SPECIAL;
    obj.lightType = LIGHT::NORMAL;
    obj.determineCurFrame();
}
 
void handleFastCustomSpringSpeeds(jjPLAYER@ play) {
        if (play.ySpeed < -32.f) {
                fastCustomSpringSpeeds[play.localPlayerID] = int(ceil((play.ySpeed + 32.f) / -0.125f));
        } else if (fastCustomSpringSpeeds[play.localPlayerID] != 0) {
                if (play.ySpeed < -31.f) {
                        fastCustomSpringSpeeds[play.localPlayerID]--;
                        play.ySpeed = -32.f;
                } else {
                        fastCustomSpringSpeeds[play.localPlayerID] = 0;
                }
        }
}

void onPlayer(jjPLAYER@ player){
	player.lightType = LIGHT::NONE;
}

void onLevelBegin() {
	MLLE::SpawnOffgrids();
}

[SOLID]
void Gift(jjOBJ@ obj) {
	if (obj.state == STATE::START) {
		obj.determineCurAnim(ANIM::CUSTOM[0], (jjRandom() % 3) * 5);
		obj.frameID = 0;
		obj.determineCurFrame();
		obj.behave(BEHAVIOR::CRATE, false);
	} else if (obj.state == STATE::DONE) {
		//obj.beSolid();
		obj.draw();
	} else if (obj.state == STATE::ACTION) {
		obj.behave(BEHAVIOR::CRATE, false);
		if (jjGameConnection == GAME::LOCAL) {
			obj.state = STATE::DONE;
			obj.creatorType = CREATOR::OBJECT;
			obj.behavior = Gift;
			obj.playerHandling = HANDLING::SPECIALDONE;
			obj.bulletHandling = HANDLING::IGNOREBULLET;
			obj.curFrame = jjAnimations[obj.curAnim] + 2;
			obj.justHit = 0;
			obj.draw();
			uint shardID = 0;
			for (uint objectID = jjObjectCount; --objectID != 0;) {
				jjOBJ@ shard = jjObjects[objectID];
				if (shard.eventID == OBJECT::SHARD && shard.isActive && shard.xOrg == obj.xPos && shard.yOrg == obj.yPos)
					shard.curAnim = obj.curAnim + 1 + (shardID++ & 3);
			}
		} else {
			obj.delete();
		}
	} else {
		obj.behave(BEHAVIOR::CRATE);
		jjDrawSpriteFromCurFrame(obj.xPos, obj.yPos - 32, obj.curFrame + 1, 1);
	}
}