Jazz Jackrabbit 2 Online

const bool MLLESetupSuccessful = MLLE::Setup(array<MLLEWeaponApply@> = {null, se::RollerMLLEWrapper(), BubbleGun::Weapon(), null, null, null, null, null, null}); ///@MLLE-Generated
#include "MLLE-Include-1.7w.asc" ///@MLLE-Generated
#pragma require "ezrivellon-MLLE-Data-2.j2l" ///@MLLE-Generated
#pragma require "ezrivellon-MLLE-Data-1.j2l" ///@MLLE-Generated
#pragma require "Carrot1.j2t" ///@MLLE-Generated
#pragma require "SSWorlds_SET1N.j2t" ///@MLLE-Generated
#pragma require "Blue Wispy Sky.j2t" ///@MLLE-Generated
#pragma require "ezrivellon.j2l" ///@MLLE-Generated
#include "BubbleGun.asc" ///@MLLE-Generated
#pragma require "BubbleGun.asc" ///@MLLE-Generated
#include "SEroller-mlle.asc" ///@MLLE-Generated
#pragma require "SEroller-mlle.asc" ///@MLLE-Generated
#pragma require "Critters.png"


void onLevelReload() {
	MLLE::ReapplyPalette();
	PaletteSetting(30, 100, solid);
	PaletteSetting(70, 130, grass);
}

array<uint8> solid = {112, 113, 114, 115, 116, 117, 118, 119, 120, 121, 122, 207, 242, 243, 244, 241, 240};
array<uint8> grass = {216, 217, 218, 219, 220, 221, 222, 223};

void PaletteSetting(uint hue, uint sat, array<uint8> ids) {
	for (uint i = 0; i < ids.length; i++) 
		jjPalette.color[ids[i]].setHSL(hue, sat, jjPalette.color[ids[i]].getLight());
    jjPalette.apply();
    jjPALCOLOR color = jjPalette.color[ids[5]];
}

void loadAssets(string filename, uint index, uint width, uint height, uint startX = 0, uint startY = 0, const jjPAL &in palette = jjPalette) {
	jjPIXELMAP asset(filename, palette);
	jjAnimSets[ANIM::CUSTOM[index]].load(
			asset,
			width,
			height,
			0,
			0,
			startX,
			startY
	);
}

void applyDarkening(int num, int id) {
	jjPAL pal = jjSpriteModeGetColorMapping(id);
	for (uint i = 0; i < 254; i++) {
		int lum = (pal.color[i].getLight() - num > 0) ? pal.color[i].getLight() - num : 0;
		pal.color[i].setHSL(pal.color[i].getHue(), pal.color[i].getSat(), (lum > 0) ? lum : 0);
	}
	jjSpriteModeSetMapping(id, jjSpriteModeGetIndexMapping(id), pal);
}

class Duck : jjBEHAVIORINTERFACE {
	uint ducks;
	void onBehave(jjOBJ@ obj) {
		if (obj.state == STATE::START) {
			obj.determineCurAnim(ANIM::CUSTOM[106], 0);
			obj.frameID = (++ducks%2);
			obj.energy = 0;
			obj.playerHandling = HANDLING::PARTICLE;
			obj.bulletHandling = HANDLING::IGNOREBULLET;
			obj.xSpeed = (jjRandom()%2 == 1) ? 0.6 + (jjRandom()%2)/10 : -(0.6 + (jjRandom()%2)/10);
			obj.counter = jjRandom()%300;
			obj.state = STATE::IDLE;
		} else if (obj.state == STATE::IDLE) {
			obj.xPos += obj.xSpeed;
			if ((++obj.counter)%300 == 1)
				jjSample(obj.xPos, obj.yPos, SOUND::ZDOG_AGRESSIV);
			obj.direction = (obj.xSpeed > 0) ? -1 : 1;
			if (jjMaskedPixel(int(obj.xPos - 5*obj.direction), int(obj.yPos)))
				obj.xSpeed = -obj.xSpeed;
		}
	}
	void onDraw(jjOBJ@ obj) {
		obj.determineCurFrame();
		jjDrawResizedSpriteFromCurFrame(obj.xPos, obj.yPos + 3*jjSin(obj.counter) + 9 , obj.curFrame, 1.1*obj.direction, 1.1, SPRITE::BRIGHTNESS, 100);
	}
}

class Bunny : jjBEHAVIORINTERFACE {
	void onBehave(jjOBJ@ obj) {
		if (obj.state == STATE::START) {
			obj.determineCurAnim(ANIM::CUSTOM[101], 0);
			obj.energy = 0;
			obj.playerHandling = HANDLING::PARTICLE;
			obj.bulletHandling = HANDLING::IGNOREBULLET;
			obj.xSpeed = 0.8;
			while (!jjMaskedPixel(int(obj.xPos), int(obj.yPos + 7)))
				obj.yPos += 1;
			obj.state = STATE::WALK;
		} else if (obj.state == STATE::WALK) {
			obj.counter++;
			obj.xPos += obj.xSpeed;
			if (jjMaskedPixel(int(obj.xPos), int(obj.yPos + 7))) {
				int deltaY = 0;
				while (jjMaskedPixel(int(obj.xPos), int(obj.yPos + deltaY + 10)))
					if (deltaY > 5)
						break;
					else deltaY++;
				obj.yPos -= 1;
			} else if (!jjMaskedPixel(int(obj.xPos), int(obj.yPos + 10)))
				obj.yPos += 1;
			if (obj.frameID == 1 && obj.counter > 70*6) {
				obj.state = STATE::IDLE;
				obj.var[0] = 100 + jjRandom()%100;
			}
		} else if (obj.state == STATE::IDLE)
			if (++obj.age == obj.var[0]) {
				obj.xSpeed = -obj.xSpeed;
				obj.age = 0;
				obj.counter = 0;
				obj.state = STATE::WALK;
			}
	}
	void onDraw(jjOBJ@ obj) {
		obj.direction = (obj.xSpeed > 0) ? -1 : 1;
		obj.determineCurFrame();
		obj.frameID = (obj.state == STATE::WALK) ? int((obj.counter%(7*6))/6) : 1;
		jjDrawResizedSpriteFromCurFrame(obj.xPos, obj.yPos, obj.curFrame, 1.1*obj.direction, 1.1, SPRITE::BRIGHTNESS, 100);
	}
}

class Cockatiel : jjBEHAVIORINTERFACE {
	void onBehave(jjOBJ@ obj) {
		if (obj.state == STATE::START) {
			obj.energy = 0;
			obj.playerHandling = HANDLING::PARTICLE;
			obj.bulletHandling = HANDLING::IGNOREBULLET;
			obj.state = STATE::IDLE;
			obj.counter = jjRandom()%50;
			while (!jjMaskedPixel(int(obj.xPos), int(obj.yPos + 7)))
				obj.yPos += 1;
		} else if (obj.state == STATE::IDLE) {
			if ((++obj.counter)%50 == 1)
				jjSample(obj.xPos, obj.yPos, SOUND::ZDOG_WAF1);
			obj.direction = (p.xPos - obj.xPos > 0) ? -1 : 1;
			if (abs(p.xPos - obj.xPos) < 40 && abs(p.yPos - obj.yPos) < 30) {
				obj.state = STATE::FLY;
				obj.counter = 0;
			}
		} else if (obj.state == STATE::FLY) {
			if (obj.counter == 0) {
				obj.var[0] = 128 + jjRandom()%70;
				obj.var[1] = 4 + jjRandom()%3;
				obj.direction = -obj.direction;
			}
			obj.xSpeed = -6*jjSin(obj.var[0]*obj.direction);
			obj.ySpeed = -6*jjCos(obj.var[0]*obj.direction);
			obj.counter++;
			if (obj.xPos > 30 && obj.yPos > 30) {
				obj.xPos += obj.xSpeed;
				obj.yPos += obj.ySpeed;
			} else {
				obj.state = STATE::WAIT;
				obj.counter = 0;
			}
		} else if (obj.state == STATE::WAIT) {
			if (++obj.counter == 70*6 && abs(p.xPos - obj.xOrg) > 32*20) {
				obj.xPos = obj.xOrg;
				obj.yPos = obj.yOrg;
				obj.counter = 0;
				obj.state = STATE::IDLE;
				while (!jjMaskedPixel(int(obj.xPos), int(obj.yPos + 7)))
					obj.yPos += 1;
			}
		}
	}
	void onDraw(jjOBJ@ obj) {
		obj.determineCurAnim(obj.state == STATE::FLY ? ANIM::CUSTOM[105] : ANIM::CUSTOM[104], 0);
		obj.determineCurFrame();
		obj.frameID = (obj.state == STATE::FLY) ? int((obj.counter%(5*6))/6) : 0;
		if (obj.state != STATE::WAIT)
			jjDrawResizedSpriteFromCurFrame(obj.xPos, obj.yPos - 6, obj.curFrame, 1.1*obj.direction, 1.1, SPRITE::BRIGHTNESS, 120, (obj.state == STATE::FLY) ? -50 : 4);
	}
}

class Squirrel : jjBEHAVIORINTERFACE {
	void onBehave(jjOBJ@ obj) {
		if (obj.state == STATE::START) {
			obj.determineCurAnim(ANIM::CUSTOM[103], 0);
			obj.energy = 0;
			obj.playerHandling = HANDLING::PARTICLE;
			obj.bulletHandling = HANDLING::IGNOREBULLET;
			obj.xSpeed = -0.8;
			while (!jjMaskedPixel(int(obj.xPos), int(obj.yPos + 7)))
				obj.yPos += 1;
			obj.state = STATE::WALK;
		} else if (obj.state == STATE::WALK) {
			obj.counter++;
			obj.xPos += obj.xSpeed;
			if (jjMaskedPixel(int(obj.xPos), int(obj.yPos + 7))) {
				int deltaY = 0;
				while (jjMaskedPixel(int(obj.xPos), int(obj.yPos + deltaY + 10)))
					if (deltaY > 5)
						break;
					else deltaY++;
				obj.yPos -= 1;
			} else if (!jjMaskedPixel(int(obj.xPos), int(obj.yPos + 10)))
				obj.yPos += 1;
			if (obj.frameID == 1 && obj.counter > 70*6) {
				obj.state = STATE::IDLE;
				obj.var[0] = 100 + jjRandom()%100;
			}
		} else if (obj.state == STATE::IDLE)
			if (++obj.age == obj.var[0]) {
				obj.xSpeed = -obj.xSpeed;
				obj.age = 0;
				obj.counter = 0;
				obj.state = STATE::WALK;
			}
	}
	void onDraw(jjOBJ@ obj) {
		obj.direction = (obj.xSpeed > 0) ? -1 : 1;
		obj.determineCurAnim(obj.state == STATE::WALK ? ANIM::CUSTOM[103] : ANIM::CUSTOM[102], 0);
		obj.determineCurFrame();
		obj.frameID = (obj.state == STATE::WALK) ? int((obj.counter%(5*6))/6) : 0;
		jjDrawResizedSpriteFromCurFrame(obj.xPos, obj.yPos, obj.curFrame, 1.1*obj.direction, 1.1, SPRITE::BRIGHTNESS, 100);
	}
}

class CannotBeShotDown : jjBEHAVIORINTERFACE {
	CannotBeShotDown(const jjBEHAVIOR &in behavior) {
		originalBehavior = behavior;
	}
	void onBehave(jjOBJ@ obj) {
		obj.behave(originalBehavior);
		if (obj.state == STATE::FLOATFALL)
			obj.state = STATE::FLOAT;
	}
	bool onObjectHit(jjOBJ@ obj, jjOBJ@ bullet, jjPLAYER@ player, int force) {
		if (bullet is null) {
			obj.behavior = originalBehavior;
			if (player.objectHit(obj, force, obj.playerHandling))
				return true;
			obj.behavior = this;
		}
		return false;
	}
	private jjBEHAVIOR originalBehavior;
}

void onLevelBegin() {
	for (int i = 1; i < 255; i++) {
		jjOBJ@ preset = jjObjectPresets[i];
		if (preset.playerHandling == HANDLING::PICKUP) {
			preset.behavior = CannotBeShotDown(preset.behavior);
		}
	}
}

class ColouredCrate : jjBEHAVIORINTERFACE {
	void onBehave(jjOBJ@ obj) {
		obj.behave(BEHAVIOR::CRATE, false);
	}
	void onDraw(jjOBJ@ obj) {
		jjDrawSpriteFromCurFrame(obj.xPos, obj.yPos, obj.curFrame, obj.direction, SPRITE::SINGLEHUE, 64);
	}
}

void onLevelLoad() {
	applyDarkening(28, 1);
	applyDarkening(15, 2);
	applyDarkening(35, 3);
	applyDarkening(25, 4);
	PaletteSetting(30, 100, solid);
	PaletteSetting(70, 130, grass);
	
	loadAssets("Critters.png", 106, 34, 28, 0, 29); //Duck
	loadAssets("Critters.png", 101, 30, 28); //Bunny
	loadAssets("Critters.png", 102, 28, 30, 0, 126); //Squirrel_Idle
	loadAssets("Critters.png", 103, 44, 26, 0, 156); //Squirrel_Walk
	loadAssets("Critters.png", 104, 26, 28, 0, 63); // Cockatiel_Idle
	loadAssets("Critters.png", 105, 34, 30, 0, 95); //Cockatiel_Fly
	
	jjSampleLoad(SOUND::ZDOG_AGRESSIV, "Duck.wav");
	jjSampleLoad(SOUND::ZDOG_WAF1, "Cockatiel.wav");
	
	jjObjectPresets[OBJECT::GUNCRATE].behavior = ColouredCrate();
	jjObjectPresets[OBJECT::LIME].behavior = Duck();
	jjObjectPresets[OBJECT::ORANGE].behavior = Bunny();
	jjObjectPresets[OBJECT::APPLE].behavior = Squirrel();
	jjObjectPresets[OBJECT::BANANA].behavior = Cockatiel();
}

void onPlayer(jjPLAYER@ play) {
	for (int i = 0; i < 1024; i++) {
		jjPARTICLE@ particle = jjParticles[i];
		if (particle.type == PARTICLE::LEAF) {
			particle.xSpeed = -1.5;
			particle.ySpeed = 0.25;
		}
	}
}

void onMain() {
	if (!jjLowDetail) {
		jjIsSnowing = jjGameTicks % 25 == 0? true:false;
	} else {
		jjIsSnowing = false;
	}
	jjSnowingType = SNOWING::LEAF;
	jjSnowingIntensity = 0;
	jjIsSnowingOutdoorsOnly = true;
}

bool onDrawAmmo(jjPLAYER@ player, jjCANVAS@ canvas) {
	return MLLE::WeaponHook.drawAmmo(player, canvas);
}